'**********************************************************************
'  Recupero i logs
'**********************************************************************
On Error Resume Next

Function Main()
  Dim rsCustomers
  
  ' Recupero il recordset con i clienti
  Set rsCustomers = CreateObject("ADODB.Recordset")
  Set rsCustomers = DTSGlobalVariables("CustomersData").value

  ' Per ogni cliente recupero i file di log
  With rsCustomers
    Do Until .EOF
      ' Leggo i Log Files di questo cliente
      Call ImportLogsByCustomer(.Fields("Cliente").Value, .Fields("URL").Value, .Fields("ForceImport").Value, .Fields("XpLogFileName").Value)

      ' Analizzo il cliente successivo
      .MoveNext
    Loop
  End With

  ' Distruggo gli oggetti allocati
  rsCustomers.Close
  Set rsCustomers = Nothing

  ' Esco dalla funzione  
   Main = DTSTaskExecResult_Success
End Function

'**********************************************************************
'  Carico ed eseguo il DTS "XpLogMaster_ImportLogsByCustomer"
'**********************************************************************
Private Sub ImportLogsByCustomer(Byval Customer, Byval URL, Byval ForceImport, Byval XpLogFileName)
  Dim oPkg
  Dim strUserID 
  Dim strPassword 
  Const SERVER = "."
  Const PKG_PASSWORD = ""
  Const PKG_NAME = "XpLogMaster_ImportLogsByCustomer"
  
  ' Credenziali di accesso
  strUserID = DTSGlobalVariables("UserID").Value
  strPassword = DTSGlobalVariables("Password").Value

  ' Istanzio la classe "DTS.Package"
  Set oPkg = CreateObject("DTS.Package")

  ' Carico il package XpLogMaster_ImportLogsByCustomer
  oPkg.LoadFromSQLServer SERVER, strUserID, strPassword, DTSSQLStgFlag_Default, PKG_PASSWORD, "", "", PKG_NAME

  With oPkg
    ' Inizializzo le Global Variables
    .GlobalVariables("Customer").Value = Customer
    .GlobalVariables("URL").Value = URL
    .GlobalVariables("ForceImport").Value = ForceImport
    .GlobalVariables("XpLogFileName").Value = XpLogFileName

    ' Eseguo il package
    .Execute
  End With

  ' Distruggo gli oggetti allocati
  oPkg.Uninitialize
  Set oPkg = Nothing
End Sub